| 1) |
Create or locate images of the digits from 0 to 9. (A good source are web page hit counters. You can also type the digits in a word processor, using a suitable font, then use a screen capture and save each digit as an individual image. |
| 2) |
Make a spot for each of the digits of the countdown. (If your countdown starts at 10,000 seconds, you will need 5 spots. Eight is probably the most you will need (a year to over 3 years). |
| 3) |
Edit the picture list for each spot and add the digit images from 0 to 9. |
| 4) |
If you are confident enough with editing the pat, you may make just one spot and then duplicate however many times you need to. (Don.t forget to change the ID.s of the new spots. Always backup your pat!) |
| 5) |
Now choose one of the spots (I usually use the first one). You will be putting the countdown script into this spot. I have included some comments in the script and will explain a little better below: |
; Thanatos' Room Countdown Script
;
; (c) Thanatos , 2003
;
; I give you the right to use and modify this code as long as this copyright
; notice and remarks remain intact. You may not redistribute the script. If
; you are asked, direct them to where you got it. I am not responsible for
; any damage that may be caused by this code. Use it at your own risk.
;
ON ENTER
{ {global } [ digits countdown message ic passed ] foreach
; ***** Change the next 2 lines for your event messages *****
"!Zoinks! There are only _d_, _h_, _m_, and _s_ until Return of the King!"
"ROTK has been in theatres for _d_, _h_, _m_, and _s_. I should have seen it a dozen times by now!"
1071644525 ;<============ Change to your event time
[
8 7 6 5 4 3 2 1 ;<============ Change these to your spots
]
digits = countdown = passed = message = 0 ic =
{ 0 swap setspotstatelocal } digits foreach
"'tock" say
}
ON INCHAT
{ {global} [ countdown adj message ic passed ] foreach
{ 1 ic = "$1" GREPSUB atoi datetime - adj =
countdown datetime adj + - diff =
diff 86400 / ds = diff ds 86400 * - diff = diff 3600 / hs = diff hs 3600 * - diff = diff 60 / ms = diff ms 60 * - ss =
{ passed msg = ds -1 * hs -1 * ms -1 * ss -1 * ss = ms = hs = ds = }
{ message msg = } ds 0 < hs 0 < ms 0 < ss 0 < OR OR OR IFELSE
{ "$1" ds itoa + " day" + {"s" + } ds 1 <> IF "$2" + GREPSUB msg = } msg "(.*)_d_(.*)" GREPSTR IF
{ "$1" hs itoa + " hour" + {"s" + } hs 1 <> IF "$2" + GREPSUB msg = } msg "(.*)_h_(.*)" GREPSTR IF
{ "$1" ms itoa + " minute" + {"s" + } ms 1 <> IF "$2" + GREPSUB msg = } msg "(.*)_m_(.*)" GREPSTR IF
{ "$1" ss itoa + " second" + {"s" + } ss 1 <> IF "$2" + GREPSUB msg = } msg "(.*)_s_(.*)" GREPSTR IF
msg SAY
0 ME SETALARM } CHATSTR "; Server local time (.*) (.*) (.*) (.*) (.*) (.*)" GREPSTR ic 0 == AND IF
}
ON ALARM
{ { global} [ digits countdown adj ] foreach
{ countdown datetime adj + -
itoa "000000000" swap +
dup STRLEN digits LENGTH - digits LENGTH SUBSTRING diff =
-1 c =
{ c ++ diff c 1 SUBSTRING ATOI SWAP SETSPOTSTATELOCAL } digits FOREACH
60 ME SETALARM } countdown datetime adj + - -1 > IF
}
